Dans la jungle de la mise à jour des champs

Sub MAJ_champs()
    ' Objectif    : Mettre à jour tous les champs présent dans le document actif
    ' Utilisation : Ne fonctionne pas si le document est protégé
    '               Ne gère pas l'exception FILENAME
    '               Ne gère pas les tables (sommaire, illustrations, références) autre part que dans
    '                 le corps du texte.
    ' Auteur      : Arnaud COTTIN (www.1forme.fr)
    ' Licence     : CC-BY-NC-SA (Vous pouvez diffuser/partager/modifier cette macro dans les même conditions,
    '                           seulement à titre personnel et citant l'auteur/site d'origine.
    
    Dim objDoc          As Document
    Dim rngStory        As Range
    Dim objChamp        As Field
    Dim i               As Integer
    Dim objShape        As Shape
    Dim objShapeCanvas  As Shape
    Dim objShapeGroupe  As Shape
    Dim objTOC          As TableOfContents
    Dim objTOF          As TableOfFigures
    Dim objTOA          As TableOfAuthorities
    
    
    On Error GoTo erreur
    Set objDoc = ActiveDocument
    With objDoc
        If .ProtectionType <> wdNoProtection Then
            MsgBox "Le document est protégé !" & vbCrLf & _
                    "Pour mettre à jour les champs, retirer cette protection.", _
                    vbOKOnly + vbInformation, "Exécution impossible"
            Set objDoc = Nothing
            Exit Sub
        End If

        Application.ScreenUpdating = False
        Application.DisplayAlerts = wdAlertsNone
        
        ' Mise à jour des stories :
        ' -------------------------
        '   wdMainTextStory     1   Article Texte principal.
        '   wd FootnotesStory   2   Article Notes de bas de page.
        '   wdEndnotesStory     3   Article Notes de fin.
        '   wdCommentsStory     4   Article Commentaires.
        '   wdTextFrameStory    5   Article Cadre de texte.

        For i = 1 To 5
            On Error Resume Next
            .StoryRanges(i).Fields.Update
            On Error GoTo erreur
            If i = 1 Then
                For Each objShape In .StoryRanges(i).ShapeRange
                    If objShape.Type = msoGroup Then
                        ' Objets groupés
                        With objShape.GroupItems
                            For Each objShapeGroupe In objShape.GroupItems
                                objShapeGroupe.TextFrame.TextRange.Fields.Update
                            Next
                        End With
                    ElseIf objShape.Type = msoCanvas Then
                        ' Zones de dessin
                        For Each objShapeCanvas In objShape.CanvasItems
                            objShapeCanvas.TextFrame.TextRange.Fields.Update
                        Next
                    Else
                        ' Objet simple
                        objShape.TextFrame.TextRange.Fields.Update
                    End If
                Next
            End If
        Next
        For Each oTOC In objDoc.TablesOfContents
            oTOC.Update
        Next
        
    ' Mise à jour des tables (sommaire, illustrations, références) dans wdMainTextStory
    ' Remarque : je n'ai pas trouvé comment mettre à jour ces tables dans les autres stories
    For Each objTOC In .TablesOfContents
        objTOC.Update
    Next
    For Each objTOF In .TablesOfFigures
        objTOF.Update
    Next
    For Each objTOA In .TablesOfAuthorities
        objTOA.Update
    Next

    End With
    ' Mise à jour des stories :
    ' -------------------------
    '   wdEvenPagesHeaderStory                 6  Article En-tête des pages paires.
    '   wdPrimaryHeaderStory                   7  Article En-tête principal.
    '   wdEvenPagesFooterStory                 8  Article Pied de page des pages paires.
    '   wdPrimaryFooterStory                   9  Article Pied de page principal.
    '   wdFirstPageHeaderStory                10  Article En-tête de la première page.
    '   wdFirstPageFooterStory                11  Article Pied de la première page.
    '
    '   wd FootnoteSeparatorStory             12  Article Séparateur de note de bas de page.
    '   wd FootnoteContinuationSeparatorStory 13  Article Séparateur de continuation de note de bas de page.
    '   wdContinuationNoticeStory             14  Article Indicateur de continuation de note de bas de page.
    '
    '   wdEndnoteSeparatorStory               15  Article Séparateur de note de fin.
    '   wdEndnoteContinuationSeparatorStory   16  Article Séparateur de continuation de note de fin.
    '   wdEndnoteContinuationNoticeStory      17  Article Indicateur de continuation de note de fin.

    Application.PrintPreview = True
    Application.PrintPreview = False
fin:
    Application.ScreenUpdating = True
    Application.DisplayAlerts = wdAlertsAll

    Set objDoc = Nothing
    Exit Sub
erreur:
    MsgBox Err.Description & "(" & Err.Number & ")"
    Resume
    GoTo fin
End Sub