0
(0)

Petite formule basée sur la formule de Haversine (Formule de haversine — Wikipédia (wikipedia.org)).

Version 1 et 2 (compatibles toutes versions d'Excel)

Exemple :

  • Point 1 :
    • B2 (Latitude1) : 47,3231°
    • C2 (Longitude1) : 5,0419°
  • Point 2 :
    • B3 (Latitude2) : 48,8567°
    • C3 (Longitude2 : 2,3522°
=2*6371*ASIN(RACINE((SIN((RADIANS(B3)-RADIANS(B2))/2))^2+COS(RADIANS(B3))*COS(RADIANS(B2))*(SIN((RADIANS(C3)-RADIANS(C2))/2))^2))


=ACOS(SIN(RADIANS(B2))*SIN(RADIANS(B3))+COS(RADIANS(B2))*COS(RADIANS(B3))*COS(RADIANS(C2-C3)))*6371

Résultat : 262,6 Km

Version 3 (versions récentes d'Excel)

Via la déclaration d'une fonction Lambda (nommée ici "DistanceCoordonnés").

=LAMBDA(_lat1;_lon1;_lat2;_lon2; LET(
     lat_1; RADIANS(_lat1);
     lon_1; RADIANS(_lon1);
     lat_2; RADIANS(_lat2);
     lon_2; RADIANS(_lon2);
     r; 6371;
     SIERREUR(
       ACOS((SIN(lat_1) * SIN(lat_2)) + (COS(lat_1) * COS(lat_2) * COS(lon_2-lon_1))) * r;
       "Coordonnées incorrectes")
))

Remarques :

  • Pour récupérer les latitudes longitudes d'un point, peut utiliser le type de données géographique Excel.
Excel Calcul de distance via les coordonnées

Merci pour votre attention bienveillante.

Article intéressant ?

Cliquez sur une étoile pour noter cet article !

Note moyenne 0 / 5. Nombre de votes : 0

Aucun vote pour l'instant ! Soyez le premier à noter ce post.

Nous sommes désolés que cet article ne vous ait pas été utile !

Améliorons cet article !

Dites nous comment nous pouvons améliorer cet article ?

Publications similaires

Laisser un commentaire

Votre adresse e-mail ne sera pas publiée. Les champs obligatoires sont indiqués avec *